Method code for $builder.action_request_cmd()

[Turn on line numbering]

---

arg cmdstr, cmd, args;
var syn, opts, request, command;

syn = "Syntax: " + cmd + " [+<ar group>] <cmt|list|view|claim|dismiss|fix> [addtl]";
[args, opts] = (> $parse_lib.opt(args, "a?ll", "f?ull") <);
if (!args)
    return ._ar__interactive();
if (listlen(args) > 1 && args[1].is_numeric())
    args = [args[2], args[1]] + sublist(args, 3);
[command, @args] = args;
if (match_template(command, "com?ment|cmt")) {
    request = (> ._ar__get_request(args, cmd + " comment") <);
    return (> ._ar__comment(sublist(args, 2), opts, request) <);
} else if (match_template(command, "l?ist")) {
    return (> ._ar__list(args, opts) <);
} else if (match_template(command, "v?iew")) {
    request = (> ._ar__get_request(args, cmd + " view") <);
    return (> ._ar__view(sublist(args, 2), opts, request) <);
} else if (match_template(command, "cl?aim")) {
    request = (> ._ar__get_request(args, cmd + " claim") <);
    return (> ._ar__claim(sublist(args, 2), opts, request) <);
} else if (match_template(command, "r?esolv|f?ix")) {
    request = (> ._ar__get_request(args, cmd + " fix") <);
    return (> ._ar__fix(sublist(args, 2), opts, request) <);
} else if (match_template(command, "d?ismiss")) {
    request = (> ._ar__get_request(args, cmd + " dismiss") <);
    return (> ._ar__dismiss(sublist(args, 2), opts, request) <);
} else {
    if (!args && command.is_numeric()) {
        request = (> ._ar__get_request([command], cmd + " view") <);
        return (> ._ar__view([], opts, request) <);
    }
    return [syn, "Unsupported command '" + command + "'"];
}

// $#Edited: 05 Oct 98 23:33 $user_bruce
// $#Edited: 08 Dec 98 23:57 $user_bruce
// $#Edited: 26 Dec 98 23:11 $brian

---

["// Created 26-Mar-1995 as a part of ColdCore, see: @help Credit"]